git » avrdude.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
# Maintainer: Jelle van der Waa <jelle@archlinux.org>
# Maintainer: Frederik Schwan <freswa at archlinux dot org>
# Contributor: Corrado Primier <bardo@aur.archlinux.org>
# Contributor: Brad Fanella <bradfanella@archlinux.us>

pkgname=avrdude
epoch=1
pkgver=8.0
pkgrel=2
pkgdesc="Download/upload/manipulate the ROM and EEPROM contents of AVR microcontrollers"
arch=('x86_64' 'armv7h')
url="https://github.com/avrdudes/avrdude/"
license=('GPL-2.0-or-later')
depends=(
  'elfutils'
  'hidapi'
  'libftdi'
  'libusb-compat'
  'readline'
  'libserialport'
)
makedepends=(
  'cmake'
  'ninja'
)
source=(
  ${pkgname}-${pkgver}.tar.gz::https://github.com/avrdudes/avrdude/archive/refs/tags/v${pkgver}.tar.gz
  https://github.com/avrdudes/avrdude/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz.sig
)
validpgpkeys=(
  'EF497ABE47ED91B3FC3D7EA54D902FF7723BDEE9' # Brian Dean <bsd@bdmicro.com>
  '5E84F980C3CAFD4BB5841070F48CA81B69A85873' # Joerg Wunsch <j@uriah.heep.sax.de>
  '56628323218C669FF578705C7E9EADC3030D34EB' # Joerg Wunsch <joerg_wunsch@uriah.heep.sax.de>
  '8FBDC99556F7C22A77DC3E1145684AB70D286F63' # Stefan Rueger <stefan.rueger@urclocks.com>
)
b2sums=('a68fa2b2553fe93e193814df68362c4eb0d74abf56a217c132c2e2347586711e34b7a4bc80168fb4103b6085f8b69cd18b142aaa54dfa4af40721732de86dd36'
        'SKIP')

build() {
  cd ${pkgname}-${pkgver}

  cmake -B build \
    -G Ninja \
    -D CMAKE_INSTALL_PREFIX=/usr \
    -D CMAKE_INSTALL_SYSCONFDIR=/etc \
    -D CMAKE_BUILD_TYPE=RelWithDebInfo \
    -D BUILD_SHARED_LIBS=1 \
    -D HAVE_LINUXGPIO=1 \
    -D HAVE_LINUXSPI=1
  ninja -C build
}

package() {
  cd ${pkgname}-${pkgver}

  DESTDIR="${pkgdir}" ninja -C build install
}