git » bash-completion.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=bash-completion
pkgver=2.11
pkgrel=3
pkgdesc='Programmable completion for the bash shell'
arch=(any)
url='https://github.com/scop/bash-completion'
license=(GPL2)
depends=(bash)
options=(!emptydirs !makeflags)
source=($url/releases/download/$pkgver/$pkgname-$pkgver.tar.xz
        $pkgname-drill.patch::https://github.com/scop/bash-completion/commit/cbec56cfd543.patch)
validpgpkeys=(A558062B6D5DA1347CD468D52B0AE2C1B09B07CB)

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 -i ../$pkgname-drill.patch
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  # bash-completion is sourced in /etc/bash.bashrc so that non-bash shell don't source it
  rm "$pkgdir/etc/profile.d/bash_completion.sh"

  # remove Slackware's makepkg completion
  rm "$pkgdir/usr/share/bash-completion/completions/makepkg"
}
sha256sums=('73a8894bad94dee83ab468fa09f628daffd567e8bef1a24277f1e9a0daf911ac'
            '1542af0a7b0cd137b2ff74aeccc1d9f09db3ccc17ff99e4dfde14bb4fe396622')