git » cage.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
# Maintainer: Brett Cornwall <ainola@archlinux.org>
# Contributor: David Runge <dvzrv@archlinux.org>

pkgname=cage
pkgver=0.1.5.r36.ge7d8780
pkgrel=1
pkgdesc="A kiosk compositor for Wayland"
arch=(armv7h)
url="https://www.hjdskes.nl/projects/cage/"
license=(MIT)
depends=(glibc wayland wlroots)
makedepends=(git libxkbcommon meson pixman scdoc wayland-protocols
xorg-server-xwayland)
optdepends=(
  'polkit: System privilege control. Required if not using seatd service'
  'xorg-server-xwayland: X11 support'
)
source=("${pkgname}::git+https://github.com/cage-kiosk/${pkgname}.git#commit=e7d8780f46277af87881e0be91cb2092541bb1d5")
install=cage.install
sha512sums=('SKIP')
validpgpkeys=(
    '13B6A35E9FD677D02CD68DBE37C445296EBC43B1' # Jente Hidskes <dev@hjdskes.nl>
    '34FF9526CFEF0E97A340E2E40FDE7BE0E88F5E48' # Simon Ser <contact@emersion.fr>
)

pkgver() {
  cd "$pkgname"
  git describe --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
  cd ..
}

build() {
  #export PKG_CONFIG_PATH='/usr/lib/wlroots0.16/pkgconfig'
  arch-meson -Dxwayland=enabled build "$pkgname"
  ninja -C build
}

#check() {
#  ninja -C build test
#}

package() {
  depends+=(libwlroots.so libxkbcommon.so libpixman-1.so)

  DESTDIR="${pkgdir}" meson install -C build
  install -vDm 644 "$pkgname/README.md" -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -vDm 644 "$pkgname/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}