git » coin-or-clp.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: spider-mario <spidermario@free.fr>
# Contributor: Daniel Ehlers <danielehlers@mindeye.net>

pkgname=coin-or-clp
pkgver=1.17.9
pkgrel=2
pkgdesc='COIN-OR linear programming solver'
arch=(x86_64 'armv7h')
url='https://github.com/coin-or/Clp'
license=(EPL)
groups=(coin-or)
depends=(coin-or-asl
         coin-or-coinutils
         coin-or-osi
         gcc-libs
         glibc
         suitesparse)
source=($pkgname-$pkgver.tar.gz::https://github.com/coin-or/Clp/archive/refs/tags/releases/$pkgver.tar.gz)
sha256sums=('b02109be54e2c9c6babc9480c242b2c3c7499368cfca8c0430f74782a694a49f')

build() {
  cd Clp-releases-$pkgver
  ./configure --prefix=/usr

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool # Fix overlinking
  make
}

check() {
  cd Clp-releases-$pkgver
  make test
}

package() {
  cd Clp-releases-$pkgver
  make DESTDIR="$pkgdir" install
}