git » cunit.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
# Maintainer: Thore Bödecker <foxxx0@archlinux.org>
# Contributor: Hanspeter Porner <dev@open-music-kontrllers.ch>
pkgname=cunit
_pkgname=CUnit
pkgver=2.1.3
_pkgver='2.1-3'
pkgrel=3
epoch=
pkgdesc='A Unit Testing Framework for C'
arch=('armv7h')
url='http://cunit.sourceforge.net'
license=('LGPL2.1')
depends=('glibc')
makedepends=('glibc' 'libtool' 'automake')
source=("https://downloads.sourceforge.net/project/cunit/$_pkgname/$_pkgver/$_pkgname-$_pkgver.tar.bz2")
sha512sums=('547b417109332446dfab8fda17bf4ccd2da841dc93f824dc90a20635bcf1fb80fb2176500d8a0906940f3f3d3e2f77b2d70a71090c9ab84ad9af43f3582bc487')

prepare() {
  cd "${srcdir}/${_pkgname}-${_pkgver}"
}

build() {
  cd "${srcdir}/${_pkgname}-${_pkgver}"

  libtoolize --force --copy
  aclocal
  autoheader
  automake --add-missing --include-deps --copy
  autoconf

  ./configure \
    --prefix=/usr \
    --enable-automated \
    --enable-basic \
    --enable-console \
    --enable-test \
    --enable-shared \
    --enable-static
  make
}

check() {
  cd "${srcdir}/${_pkgname}-${_pkgver}"
  ./CUnit/Sources/Test/test_cunit
}

package() {
  cd "${srcdir}/${_pkgname}-${_pkgver}"

  make DESTDIR="${pkgdir}/" install

  rm -r "${pkgdir}/usr/share/CUnit"
  mv "${pkgdir}/usr/doc" "${pkgdir}/usr/share/"
}