git » editline.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: George Rawlinson <george@rawlinson.net.nz>
# Contributor: Immae <ismael.bouya@normalesup.org>

pkgname=editline
pkgver=1.17.1
pkgrel=3
pkgdesc='A readline() replacement for UNIX without termcap (ncurses)'
arch=('armv7h')
url='http://troglobit.com/editline.html'
license=('BSD')
depends=('glibc')
makedepends=('git')
provides=('libeditline.so')
install="$pkgname.install"
# We need one post-1.17.1 build-fix
source=($pkgname-$pkgver::git+https://github.com/troglobit/editline.git#commit=425584840c09f83bb8fedbf76b599d3a917621ba)

#"$pkgname-$pkgver.tar.gz::https://github.com/troglobit/$pkgname/archive/$pkgver.tar.gz"

build () {
  cd "$pkgname-$pkgver"
  ./autogen.sh
  ./configure --prefix=/usr
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  
  # avoid libedit conflict
  mv "$pkgdir"/usr/share/man/man3/editline{,-troglobit}.3

  # license
  install -Dm0644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"

  # additional documentation
  cp -vrt "$pkgdir/usr/share/doc/$pkgname" docs
}
sha256sums=('a31109a073815037907f786d8a520d25538d49d7193bd20b48f75ba1d2844bc4')