git » ext4fuse-git.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: Chih-Hsuan Yen <yan12125@gmail.com>

_pkgname=ext4fuse
pkgname=$_pkgname-git
pkgver=0.1.3.r20.g6b23d8d
pkgrel=2
pkgdesc="EXT4 implementation for FUSE"
arch=('i686' 'x86_64' 'armv7h')
license=('GPL2')
url='https://github.com/gerard/ext4fuse'
depends=('glibc' 'fuse2')
makedepends=('git')
source=("git+https://github.com/gerard/ext4fuse")
sha256sums=('SKIP')
provides=('ext4fuse')

pkgver() {
  cd $_pkgname
  ( set -o pipefail
    git describe --long --tag 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
  )
}

prepare() {
  cd $_pkgname

  mkdir -p "$srcdir"/tmp
  sed -i "s#mktemp /tmp#mktemp \"$srcdir\"/tmp#" test/lib.sh
}

build() {
  cd $_pkgname

  make
}

check() {
  cd $_pkgname

  # sudo make test
}

package() {
  cd $_pkgname

  install -Dm755 ext4fuse "$pkgdir"/usr/bin/ext4fuse
}