git » ftr-site-config-git.git » master » tree

[master] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
# -*- sh -*-

# Maintainer: Klaus Alexander Seistrup <$(echo 0x1fd+d59decfa=40 | tr 0-9+a-f=x ka-i@p-u.l)>

pkgname='ftr-site-config-git'
_pkgname="${pkgname/-git/}"
pkgver=2025.12.13.r3763.ga5f174c
pkgrel=1
pkgdesc='Full-Text RSS: Site-specific article extraction rules (development version)'
arch=('any')
url='https://github.com/fivefilters/ftr-site-config'
license=('CC0-1.0')  # SPDX-License-Identifier: CC0-1.0
makedepends=('findutils' 'git')
depends=()
optdepends=()
source=(
  "$_pkgname::git+$url.git"
  'CC0-1.0.txt::https://creativecommons.org/publicdomain/zero/1.0/legalcode.txt'
)
provides=("$_pkgname")
conflicts=("${provides[@]}")
sha256sums=('SKIP' 'SKIP')
options=('!strip')

pkgver() {
  cd "$_pkgname"

  ( set -o pipefail
    git describe --long --abbrev=7 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' \
    || {
      _today=''; _today=$(printf '%(%Y.%-m.%-d)T')
      printf '%s.r%s.g%s' "$_today" \
        "$(git rev-list  --count HEAD)" \
	"$(git rev-parse --short=7 HEAD)"
    }
  )
}

prepare() {
  cd "$_pkgname"

  git clean -dfx
}

build() {
  cd "$_pkgname"

  : pass
}

package() {
  cd "$_pkgname"

  install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" "$srcdir/CC0-1.0.txt"
  install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.txt
  install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" README.md

  find . -maxdepth 1 -type f -name '\.*.txt' -print0 \
  | xargs -r0 install -Dm0644 -t "$pkgdir/usr/share/$_pkgname"

  find . -maxdepth 1 -type f -name   '*.txt' -print0 \
  | xargs -r0 install -Dm0644 -t "$pkgdir/usr/share/$_pkgname"

  rm -f "$pkgdir/usr/share/$_pkgname/LICENSE.txt"

  for _dir in doc licenses; do
    cd "$pkgdir/usr/share/$_dir" && ln -sr "$pkgname" "$_pkgname"
  done
}

# eof