git » fuse3.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
pkgbase=fuse3
pkgname=(fuse-common fuse3)
pkgver=3.16.2
pkgrel=1
pkgdesc='Interface for userspace programs to export a filesystem to the Linux kernel'
url='https://github.com/libfuse/libfuse'
arch=("armv7h" 'aarch64')
license=('GPL2')
makedepends=('pkgconf' 'meson')
options=('!emptydirs')
source=(https://github.com/libfuse/libfuse/releases/download/fuse-$pkgver/fuse-$pkgver.tar.gz)
sha256sums=('f797055d9296b275e981f5f62d4e32e089614fc253d1ef2985851025b8a0ce87')

build() {
  cd fuse-$pkgver

  rm -rf build
  meson --prefix=/usr -D examples=false . build
  cd build
  ninja
}

package_fuse-common() {
  pkgdesc="Common files for fuse2/3 packages"
  backup=(etc/fuse.conf)

  install -Dm644 fuse-${pkgver}/util/fuse.conf "${pkgdir}"/etc/fuse.conf
}

package_fuse3() {
  depends=('fuse-common' 'glibc')

  cd fuse-$pkgver/build

  DESTDIR="${pkgdir}" ninja install

  rm -r "${pkgdir}"/etc/init.d
  rm -r "${pkgdir}"/etc/fuse.conf

  # static device nodes are handled by udev
  rm -r "${pkgdir}"/dev
}