git » gavl.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Robert Emil Berge <filoktetes@linuxophic.org>
# Contributor: Mateusz Herych <heniekk@gmail.com>

pkgname=gavl
pkgver=1.4.0
pkgrel=7
pkgdesc='Low level library, upon which multimedia APIs can be built'
arch=('x86_64' 'armv7h')
url='http://gmerlin.sourceforge.net/'
license=('GPL-2.0-or-later')
depends=('glibc')
makedepends=('doxygen')
source=("https://downloads.sourceforge.net/gmerlin/$pkgname-$pkgver.tar.gz")
sha256sums=('51aaac41391a915bd9bad07710957424b046410a276e7deaff24a870929d33ce')

prepare() {
  cd $pkgname-$pkgver
  # Fix build
  sed -i 's|volume_test_LDADD = ../gavl/libgavl.la|volume_test_LDADD = -lm ../gavl/libgavl.la|' src/Makefile.{am,in}
  sed -i 's/LDFLAGS="$GMERLIN_DEP_RPATH"/LDFLAGS="$LDFLAGS $GMERLIN_DEP_RPATH"/' configure{,.ac}
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --with-cpuflags=none
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}