git » geoip.git » main

# Maintainer: Juergen Hoetzel <juergen@archlinux.org>
# Contributor: Manolis Tzanidakis <manolis@archlinux.org>

pkgname=geoip
pkgver=1.6.12
pkgrel=2
pkgdesc="Non-DNS IP-to-country resolver C library & utils"
arch=('x86_64' 'armv7h')
url="https://www.maxmind.com/app/c"
license=('GPL')
depends=('zlib' 'geoip-database')
optdepends=('geoip-database-extra: city/ASN databases (not needed for country lookups)')
makedepends=('autoconf' 'libtool')
options=('!emptydirs')
source=($pkgname-$pkgver.tar.gz::https://github.com/maxmind/${pkgname}-api-c/archive/v${pkgver}.tar.gz)
sha256sums=('99b119f8e21e94f1dfd6d49fbeed29a70df1544896e76cd456f25e397b07d476')

prepare() {
  cd geoip-api-c-$pkgver
  ./bootstrap
}

build() {
  cd geoip-api-c-$pkgver

  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --sysconfdir=/etc/geoip
  make
}

package() {
  cd geoip-api-c-$pkgver
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et:
git » geoip.git » main » tree

[main] / PKGBUILD
