git » gi-docgen.git » main

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>

pkgname=gi-docgen
pkgver=2023.3
pkgrel=2
pkgdesc="Documentation generator for GObject-based libraries"
url="https://gnome.pages.gitlab.gnome.org/gi-docgen/"
arch=(any)
license=(
  "Apache-2.0 OR GPL-3.0-or-later"
  BSD-2-Clause
)
depends=(
  jinja2
  python-magic
  python-markdown
  markupsafe
  python-packaging
  python-pygments
  python-typogrify
)
makedepends=(
  git
  python-build
  python-installer
  python-setuptools
  python-wheel
)
_commit=96f2e9b93e1d8a5338eb05b87fd879856ab7b3cc  # tags/2023.3^0
source=("git+https://gitlab.gnome.org/GNOME/gi-docgen.git#commit=$_commit")
b2sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd $pkgname
}

build() {
  cd $pkgname
  python -m build --wheel --no-isolation
}

package() {
  cd $pkgname
  python -m installer --destdir="$pkgdir" dist/*.whl
}

# vim:set sw=2 sts=-1 et:
git » gi-docgen.git » main » tree

[main] / PKGBUILD
