git » glad.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>

pkgname=glad
pkgver=2.0.6
pkgrel=3
pkgdesc='Multi-Language Vulkan/GL/GLES/EGL/GLX/WGL Loader-Generator based on the official specs'
url='https://github.com/Dav1dde/glad'
arch=('any')
license=('MIT')
depends=('python' 'jinja2' 'python-lxml' 'python-setuptools')
makedepends=('python-build' 'python-installer' 'python-wheel')
#checkdepends=('python-pytest' 'xorgproto' 'libx11' 'glfw-x11' 'xorg-server-xvfb' 'mingw-w64-gcc' 'wine' 'rust' 'libxinerama')
source=(${url}/archive/refs/tags/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
sha512sums=('ad7e0544fdd07ba7e091ed8a985deb27f05affb0a830b8132d7c03d6690b57139b25433303260e3affba7b11c0dad38358fcd4ff5b7b30e7ca193e8beed8db48')
b2sums=('d18a9ee4445a603d1f277db24bca9e21bb87f919fa366ee307dba21ffbfef7be690c3e924ab405c54a9cd8dc1d487297586020a04e04afe48779fdb39f9b81dd')

build() {
  cd ${pkgname}-${pkgver}
  python -m build --wheel --no-isolation
}

#check() {
#  cd ${pkgname}-${pkgver}
#  rm test/c/run/wgl -r # Remove Windows tests
#  PRINT_MESSAGE=1 \
#  EXIT_ON_FAILURE=1 \
#  xvfb-run ./utility/test.sh
#}

package() {
  cd ${pkgname}-${pkgver}
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm 644 README.md -t "$pkgdir"/usr/share/doc/"$pkgname"
  install -Dm 644 LICENSE -t "$pkgdir"/usr/share/licenses/"$pkgname"
}

# vim: ts=2 sw=2 et: