git » graphicsmagick.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Anton Leontiev <bunder@t-25.ru>

pkgname=graphicsmagick
pkgver=1.3.43
pkgrel=1
pkgdesc='Image processing system'
url='http://www.graphicsmagick.org/'
arch=(x86_64 'armv7h')
license=(MIT)
depends=(bzip2
         freetype2
         lcms2
         libltdl
         libpng
         libsm
         libtiff
         libwebp
         libxext
         xz)
makedepends=(jasper
             libheif
#             libjxl
             libwmf
             libxml2
             perl)
optdepends=('jasper: jp2 module'
            'libwmf: wmf module'
            'libxml2: msl, svg, url modules'
            'ghostscript: pdf, ps modules'
            'libheif: heic module'
#            'libjxl: jpeg-xl module'
)
provides=(Magick.so
          libGraphicsMagickWand.so
          libGraphicsMagick.so
          libGraphicsMagick++-Q16.so)
_archive="GraphicsMagick-$pkgver"
source=("https://downloads.sourceforge.net/project/$pkgname/$pkgname/$pkgver/$_archive.tar.xz")
sha256sums=('2b88580732cd7e409d9e22c6116238bef4ae06fcda11451bf33d259f9cbf399f')

options=('!emptydirs' 'libtool')

prepare() {
	cd "$_archive"
	sed -e "s:freetype_config='':freetype_config='/usr/bin/pkg-config freetype2':g" -i configure
}

build() {
	cd "$_archive"
	./configure \
		--prefix=/usr \
		--enable-shared \
		--with-modules \
		--with-perl \
		--with-quantum-depth=16 \
		--with-magick_plus_plus \
		--with-threads
	make
}

package() {
	cd "$_archive"
	make DESTDIR="$pkgdir" install
	install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" Copyright.txt
	# Install perl bindings
	# The patching was introduced in order to build perl module without installing package itself and
	# not to introduce unnecessary path into LD_RUN_PATH
	cd PerlMagick
	sed -i -e "s:'LDDLFLAGS'  => \"\(.*\)\":'LDDLFLAGS'  => \"-L${pkgdir}/usr/lib \1\":" Makefile.PL
	perl Makefile.PL INSTALLDIRS=vendor PREFIX=/usr DESTDIR="${pkgdir}"
	sed -i -e "s/LDLOADLIBS =/LDLOADLIBS = -lGraphicsMagick/" Makefile
	make
	make install
	# Remove perllocal.pod and .packlist
	rm -r "$pkgdir"/usr/lib/perl5/*/core_perl
	rm "$pkgdir"/usr/lib/perl5/*/vendor_perl/auto/Graphics/Magick/.packlist
}