git » gupnp-igd.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Eric Bélanger <eric@archlinux.org>

pkgname=gupnp-igd
pkgver=1.6.0
pkgrel=1
pkgdesc="A library to handle UPnP IGD port mapping"
url="https://wiki.gnome.org/Projects/GUPnP"
arch=(x86_64 'armv7h')
license=(LGPL)
depends=(gupnp)
makedepends=(
  git
  gobject-introspection
  gtk-doc
  meson
)
_commit=e60764858374d776869605d39e5e4d1033e9ad4a  # tags/1.6.0^0
source=("git+https://gitlab.gnome.org/GNOME/gupnp-igd.git#commit=$_commit")
b2sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd $pkgname
}

build() {
  arch-meson $pkgname build -D gtk_doc=true
  meson compile -C build
}

#check() {
#  # No multicast in our containers?
#  meson test -C build --print-errorlogs || :
#}

package() {
  depends+=(libg{lib,object,io}-2.0.so libg{ssdp,upnp}-1.6.so)
  provides+=(libgupnp-igd-1.6.so)

  meson install -C build --destdir "$pkgdir"
}

# vim:set sw=2 sts=-1 et: