git » id3lib.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Guillaume ALAUX <guillaume@archlinux.org>
# Contributor: Jochem Kossen   <j.kossen@home.nl>
# Contributor: rtfreedman      <rob.til.freedman@googlemail.com>

pkgname=id3lib
pkgver=3.8.3
pkgrel=19
pkgdesc='Library for reading, writing, and manipulating ID3v1 and ID3v2 tags'
arch=(x86_64 'armv7h')
license=(GPL-2.0-only)
url='http://id3lib.sourceforge.net/'
depends=(gcc-libs
         glibc
         zlib)
source=(https://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.gz
        00-add-libz-to-compilation.patch
        05-create-m4-directory.patch
        10-fix-compilation-with-cpp-headers.patch
        15-fix-headers-of-main-functions.patch
        20-create-manpages.patch
        30-fix-utf16.patch
        40-deal-with-mkstemp.patch
        50-remove-outdated-check.patch
        60-add-c-wrapper-functions.patch
        60-fix_make_check.patch
        60-id3lib-missing-nullpointer-check.patch
        60-spelling.patch
        61-fix_vbr_stack_smash.patch)
sha256sums=('2749cc3c0cd7280b299518b1ddf5a5bcfe2d1100614519b68702230e26c7d079'
            'e884395cf0bd7b44a550fc8785d79c0992d749be1edc45b00d289cbbd179c6d5'
            'c41ec6889b775119f71c25fa09bb5110bcf550a14e6aac80597479df453de5fb'
            '5fb24595095596ff55d876fb3e5277000f04c4f7a3e07aff5c05e11639dc2165'
            '042deb7c2df1afa0851622b6086e8eb4b007cc6cfcd70210852d5c25e39b08b1'
            '97442e14a5147df36f35d6a396e2b3fb6e155060ec672d91a68bd1a742234b4e'
            'a7cce4176df773677bfc6a527a0465d460fe60a269402af9bdfc9dd6104ea6a4'
            'd7999cdb425ba8013dd11da7fb570e875d368e5b1236c2b094abee8446f04218'
            'f908af7715fb164081d191c766b040cefa0a94f1414e98f60bc38b3e0b1aa309'
            '1b06c5d2c36e6a1f2236c4603a934d8cd675414dcfd52b997cb584404c0bc77d'
            '88aded7423f266d2fedb0eef9dbb272b53cc776ae98bd71dd5afb30b6ac48515'
            '85f20c4d3467f48df1bcaa4150bae55e95270cabb542589f167a914b2f553d04'
            'b31bfa7213325776f6784a684f082814d3affb050d36a7c41cf1b1df07228c5c'
            '5a24d460c9dd1e643ac57b817ea9cec87f44c1d49381065f83879b2eea36adf7')

prepare() {
  cd $pkgname-$pkgver

  patch -p1 -i ../00-add-libz-to-compilation.patch
  patch -p1 -i ../05-create-m4-directory.patch
  patch -p1 -i ../10-fix-compilation-with-cpp-headers.patch
  patch -p1 -i ../15-fix-headers-of-main-functions.patch
  patch -p1 -i ../20-create-manpages.patch
  patch -p1 -i ../30-fix-utf16.patch
  patch -p1 -i ../40-deal-with-mkstemp.patch
  patch -p1 -i ../60-add-c-wrapper-functions.patch
  patch -p1 -i ../60-fix_make_check.patch
  patch -p1 -i ../60-id3lib-missing-nullpointer-check.patch
  patch -p1 -i ../60-spelling.patch
  patch -p1 -i ../61-fix_vbr_stack_smash.patch
  patch -p1 -i ../50-remove-outdated-check.patch

  libtoolize -fc
  aclocal
  autoconf
  automake --add-missing --copy
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool # Fix overlinking
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  install -d "$pkgdir"/usr/share/man/man1
  cp doc/man/* "$pkgdir"/usr/share/man/man1
}