git » iotop-c.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: Chistian Heusel <gromit@archlinux.org>
# Contributor: Rumen Jekov <rvjekov@gmail.com>
# Contributor: Boian Bonev <bbonev@ipacct.com>

pkgname=iotop-c
pkgver=1.26
pkgrel=2
pkgdesc="simple top-like I/O monitor (implemented in C)"
arch=('armv7h')
url="https://github.com/Tomas-M/iotop"
license=('GPL-2.0-or-later')
depends=('glibc' 'ncurses')
makedepends=('pkgconf')
conflicts=('iotop')
provides=('iotop')
source=(${url}/releases/download/v${pkgver}/iotop-${pkgver}.tar.xz{,.asc})
validpgpkeys=('BA60BC20F37E59444D6D25001365720913D2F22D')
sha256sums=('8739dc429c9c07f51955cb01ccfba081c9776f63134d24a2454e2598873fcd1e'
            'SKIP')

prepare() {
	cd iotop-${pkgver}
	sed -i 's/sbin/bin/g' Makefile
	sed -i '/STRIP/d' Makefile
}

build() {
	cd iotop-${pkgver}
	make DESTDIR="${pkgdir}" V=1
}

package() {
	cd iotop-${pkgver}
	make DESTDIR="${pkgdir}" install
}