git » java-openjdk.git » main » tree

# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Frederik Schwan <freswa at archlinux dot org>
# Contributor: Guillaume ALAUX <guillaume@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - drop pandoc makedepend
#  - specify ARM _JARCH's
#  - use zero on ARMv5, adjusted _imgdir
#  - don't build docs, removed docs package; takes a day to build
#  - replace --with-num-cores with --with-jobs
#  - remove --enable-jvm-feature-zgc from configure, not supported on ARM
#  - set --with-native-debug-symbols=none, OOM

# TODO add test, see about packaging jtreg and using it here
# TODO see about building with OpenJDK10
# TODO add javazi
# TODO when IcedTea provides it, package icedtea-web and add it as optdepends
# TODO package OpenJFX for OpenJDK10 and add it as optdepends

## EXPLORATIONS
# TODO extract a jmods package from jdk10-openjdk?
# TODO extract a jdk-headless package?

pkgbase=java-openjdk
pkgname=(
  jdk-openjdk
  jre-openjdk
  jre-openjdk-headless
  openjdk-src
)
# on a majorver change, don't forget to update the misc files that come along this PKGBUILD
_majorver=25
_minorver=0
_securityver=1
_updatever=8
pkgver=${_majorver}.${_minorver}.${_securityver}.u${_updatever}
# pkgver=${_majorver}.u${_updatever}
pkgrel=3
_git_tag=jdk-${_majorver}.${_minorver}.${_securityver}+${_updatever}
# _git_tag=jdk-${_majorver}+${_updatever}
arch=('x86_64' 'aarch64' 'armv7h')
url='https://openjdk.java.net/'
license=('LicenseRef-Java')
makedepends=(
  "java-environment>=22"
  alsa-lib
  bash
  cpio
  freetype2
  gcc-libs
  giflib
  glibc
  graphviz
  harfbuzz
  lcms2
  libcups
  libelf
  libjpeg-turbo
  libnet
  libpng
  libx11
  libxext
  libxrandr
  libxrender
  libxt
  libxtst
  unzip
  zip
)
optdepends=(
  'gvfs: open links e.g. hyperlinks'
)             
source=(
  https://github.com/openjdk/jdk${_majorver}u/archive/${_git_tag}.tar.gz
  freedesktop-java.desktop
  freedesktop-jconsole.desktop
  freedesktop-jshell.desktop
)
sha256sums=('d530e3d08ebda8ddb13431e3b54eaaef2329704d4e096cbf815353fcb8646a83'
            'b800c73efde1b5655fff8d6926c6390e306b375ea72a3066a946011faa05de5a'
            'a308c7b85339a03718583ceb8b37140fb23c754c30e50f60cee19d7b04c747ba'
            'cd83d0a053954ea46a37b057e73668d5933deac873630aeaca06dc072c532413')

case "${CARCH}" in
  x86_64) _JARCH='x86_64';;
  i686)   _JARCH='x86';;
  riscv64)_JARCH='riscv64';;
  arm*)    _JARCH='arm';;
  aarch64) _JARCH='aarch64';;
esac

_jvmdir=/usr/lib/jvm/java-${_majorver}-openjdk
_jdkdir=jdk${_majorver}u-${_git_tag//+/-}
if [[ $CARCH == "arm" ]]; then
  _imgdir=${_jdkdir}/build/linux-${_JARCH}-zero-release/images
else
  _imgdir=${_jdkdir}/build/linux-${_JARCH}-server-release/images
fi

_nonheadless=(
  lib/libawt_xawt.so
  lib/libjawt.so
  lib/libjsound.so
  lib/libsplashscreen.so
)

_commondeps=(
  'java-runtime-common>=3'
  #ca-certificates-utils
  freetype2
  gcc-libs
  glibc
  harfbuzz
  lcms2
  libfreetype.so
  libharfbuzz.so
  libjpeg.so
  libjpeg-turbo
  liblcms2.so
  libnet
  nss
)

build() {
  cd ${_jdkdir}

  [[ $CARCH != "aarch64" ]] && export MAKEFLAGS="-j2"

  # remove -j from MAKEFLAGS to prevent build fail
  local MAKEFLAG_J=$(echo ${MAKEFLAGS} | sed -En 's/.*-j([0-9]+).*/\1/p')
  export MAKEFLAGS=${MAKEFLAGS/-j${MAKEFLAG_J}/}

  # Avoid optimization of HotSpot to be lowered from O3 to O2
  local _CFLAGS="${CFLAGS//-O2/-O3} ${CPPFLAGS} -fcommon"
  local _CXXFLAGS="${CXXFLAGS//-O2/-O3} ${CPPFLAGS} -fcommon"
  local _LDFLAGS=${LDFLAGS}
  if [[ ${CARCH} = i686 ]]; then
    echo "Removing '-fno-plt' from CFLAGS and CXXFLAGS to prevent build fail with this architecture"
    _CFLAGS=${CFLAGS/-fno-plt/}
    _CXXFLAGS=${CXXFLAGS/-fno-plt/}
  fi

  # TODO: Should be rechecked for the next releases
  # compiling with -fexceptions leads to:
  # /usr/bin/ld: /build/java-openjdk/src/jdk17u-jdk-17.0.3-2/build/linux-x86_64-server-release/hotspot/variant-server/libjvm/objs/zPhysicalMemory.o: in function `ZList<ZMemory>::~ZList()':
  # /build/java-openjdk/src/jdk17u-jdk-17.0.3-2/src/hotspot/share/gc/z/zList.hpp:54: undefined reference to `ZListNode<ZMemory>::~ZListNode()'
  # collect2: error: ld returned 1 exit status
  _CFLAGS=${CFLAGS/-fexceptions/}
  _CXXFLAGS=${CXXFLAGS/-fexceptions/}

  # CFLAGS, CXXFLAGS and LDFLAGS are ignored as shown by a warning
  # in the output of ./configure unless used like such:
  #  --with-extra-cflags="${CFLAGS}"
  #  --with-extra-cxxflags="${CXXFLAGS}"
  #  --with-extra-ldflags="${LDFLAGS}"
  # See also paragraph "Configure Control Variables from "jdk${_majorver}-${_git_tag}/common/doc/building.md
  unset CFLAGS
  unset CXXFLAGS
  unset LDFLAGS

  if [[ $CARCH == "arm" ]]; then
    _variants='zero'
  else
    _variants='server'
  fi

  bash configure \
    --with-version-string="${_majorver}.${_minorver}.${_securityver}" \
    --with-stdc++lib=dynamic \
    --with-extra-cflags="${_CFLAGS}" \
    --with-extra-cxxflags="${_CXXFLAGS}" \
    --with-extra-ldflags="${_LDFLAGS}" \
    --with-libjpeg=system \
    --with-giflib=system \
    --with-libpng=system \
    --with-lcms=system \
    --with-zlib=system \
    --with-harfbuzz=system \
    --with-native-debug-symbols=none \
    --enable-unlimited-crypto \
    --disable-warnings-as-errors \
    --with-jvm-variants=$_variants \
    --with-vendor-name="Arch Linux"

  make images legacy-jre-image

  # https://bugs.openjdk.java.net/browse/JDK-8173610
  find "${srcdir}/${_imgdir}" -iname '*.so' -exec chmod +x {} \;
}

check() {
  cd ${_jdkdir}
  # TODO package jtreg
  # make -k check
}

package_jre-openjdk-headless() {
  pkgdesc="OpenJDK Java ${_majorver} headless runtime environment"
  depends=(
    "${_commondeps[@]}"
  )
  optdepends=(
    'java-rhino: for some JavaScript support'
  )
  provides=(
    "java-runtime-headless=${_majorver}"
    "java-runtime-headless-openjdk=${_majorver}"
    "jre${_majorver}-openjdk-headless=${pkgver}-${pkgrel}"
  )
  conflicts=(
    jdk-openjdk
    jre-openjdk
  )
  backup=(
    etc/${pkgbase}/logging.properties
    etc/${pkgbase}/management/jmxremote.access
    etc/${pkgbase}/management/jmxremote.password.template
    etc/${pkgbase}/management/management.properties
    etc/${pkgbase}/net.properties
    etc/${pkgbase}/security/java.policy
    etc/${pkgbase}/security/java.security
    etc/${pkgbase}/security/policy/README.txt
    etc/${pkgbase}/security/policy/limited/default_US_export.policy
    etc/${pkgbase}/security/policy/limited/default_local.policy
    etc/${pkgbase}/security/policy/limited/exempt_local.policy
    etc/${pkgbase}/security/policy/unlimited/default_US_export.policy
    etc/${pkgbase}/security/policy/unlimited/default_local.policy
    etc/${pkgbase}/sound.properties
  )
  install=install_jre-openjdk-headless.sh

  cd ${_imgdir}/jre

  install -dm 755 "${pkgdir}${_jvmdir}"

  cp -a bin lib \
    "${pkgdir}${_jvmdir}"

  for f in "${_nonheadless[@]}"; do
    rm "${pkgdir}${_jvmdir}/${f}"
  done

  # Conf
  install -dm 755 "${pkgdir}/etc"
  cp -r conf "${pkgdir}/etc/${pkgbase}"
  ln -s /etc/${pkgbase} "${pkgdir}/${_jvmdir}/conf"

  # Legal
  install -dm 755 "${pkgdir}/usr/share/licenses"
  cp -r legal "${pkgdir}/usr/share/licenses/${pkgbase}"
  ln -s ${pkgbase} "${pkgdir}/usr/share/licenses/${pkgname}"
  ln -s /usr/share/licenses/${pkgbase} "${pkgdir}/${_jvmdir}/legal"

  # Man pages
  for f in bin/*; do
    f=$(basename "${f}")
    _man=../jdk/man/man1/"${f}.1"
    test -f "${_man}" && install -Dm 644 "${_man}" "${pkgdir}/usr/share/man/man1/${f}-openjdk${_majorver}.1"
  done
  ln -s /usr/share/man "${pkgdir}/${_jvmdir}/man"

  # Link JKS keystore from make-ca
  rm -f "${pkgdir}${_jvmdir}/lib/security/cacerts"
  ln -sf /etc/pki/tls/java/cacerts "${pkgdir}${_jvmdir}/lib/security/cacerts"
}

package_jre-openjdk() {
  pkgdesc="OpenJDK Java ${_majorver} full runtime environment"
  depends=(
    "${_commondeps[@]}"
    giflib
    libgif.so
    libpng
  )
  optdepends=(
    'alsa-lib: for basic sound support'
    'gtk3: for the Gtk+ 3 look and feel - desktop usage'
  )
  provides=(
    "java-runtime=${_majorver}"
    "java-runtime-openjdk=${_majorver}"
    "jre${_majorver}-openjdk=${pkgver}-${pkgrel}"
    "java-runtime-headless=${_majorver}"
    "java-runtime-headless-openjdk=${_majorver}"
    "jre${_majorver}-openjdk-headless=${pkgver}-${pkgrel}"
  )
  conflicts=(
    jdk-openjdk
    jre-openjdk-headless
  )
  backup=(
    etc/${pkgbase}/logging.properties
    etc/${pkgbase}/management/jmxremote.access
    etc/${pkgbase}/management/jmxremote.password.template
    etc/${pkgbase}/management/management.properties
    etc/${pkgbase}/net.properties
    etc/${pkgbase}/security/java.policy
    etc/${pkgbase}/security/java.security
    etc/${pkgbase}/security/policy/README.txt
    etc/${pkgbase}/security/policy/limited/default_US_export.policy
    etc/${pkgbase}/security/policy/limited/default_local.policy
    etc/${pkgbase}/security/policy/limited/exempt_local.policy
    etc/${pkgbase}/security/policy/unlimited/default_US_export.policy
    etc/${pkgbase}/security/policy/unlimited/default_local.policy
    etc/${pkgbase}/sound.properties
  )
  install=install_jre-openjdk.sh

  cd ${_imgdir}/jre

  install -dm 755 "${pkgdir}${_jvmdir}"

  cp -a bin lib \
    "${pkgdir}${_jvmdir}"

  for f in "${_nonheadless[@]}"; do
    install -Dm 755 ${f} "${pkgdir}${_jvmdir}/${f}"
  done

  # Conf
  install -dm 755 "${pkgdir}/etc"
  cp -r conf "${pkgdir}/etc/${pkgbase}"
  ln -s /etc/${pkgbase} "${pkgdir}/${_jvmdir}/conf"

  # Legal
  install -dm 755 "${pkgdir}/usr/share/licenses"
  cp -r legal "${pkgdir}/usr/share/licenses/${pkgbase}"
  ln -s ${pkgbase} "${pkgdir}/usr/share/licenses/${pkgname}"
  ln -s /usr/share/licenses/${pkgbase} "${pkgdir}/${_jvmdir}/legal"

  # Man pages
  for f in bin/*; do
    f=$(basename "${f}")
    _man=../jdk/man/man1/"${f}.1"
    test -f "${_man}" && install -Dm 644 "${_man}" "${pkgdir}/usr/share/man/man1/${f}-openjdk${_majorver}.1"
  done
  ln -s /usr/share/man "${pkgdir}/${_jvmdir}/man"

  # Link JKS keystore from ca-certificates-utils
  rm -f "${pkgdir}${_jvmdir}/lib/security/cacerts"
  ln -sf /etc/pki/tls/java/cacerts "${pkgdir}${_jvmdir}/lib/security/cacerts"

  # Desktop files
  for f in java; do
    install -Dm 644 \
      "${srcdir}/freedesktop-${f}.desktop" \
      "${pkgdir}/usr/share/applications/${f}-${pkgbase}.desktop"
  done
}

package_jdk-openjdk() {
  pkgdesc="OpenJDK Java ${_majorver} development kit"
  depends=(
    "${_commondeps[@]}"
    'java-environment-common=3'
   # ca-certificates-utils
    freetype2
    harfbuzz
    hicolor-icon-theme
    lcms2
    libelf
    libfreetype.so
    libgif.so
    libharfbuzz.so
    libjpeg.so
    libjpeg-turbo
    liblcms2.so
    libnet
    libpng
    nss
  )
  optdepends=(
    'java-rhino: for some JavaScript support'
    'alsa-lib: for basic sound support'
    'gtk3: for the Gtk+ 3 look and feel - desktop usage'
  )
  provides=(
    "java-environment=${_majorver}"
    "java-environment-openjdk=${_majorver}"
    "jdk${_majorver}-openjdk=${pkgver}-${pkgrel}"
    "java-runtime=${_majorver}"
    "java-runtime-openjdk=${_majorver}"
    "jre${_majorver}-openjdk=${pkgver}-${pkgrel}"
    "java-runtime-headless=${_majorver}"
    "java-runtime-headless-openjdk=${_majorver}"
    "jre${_majorver}-openjdk-headless=${pkgver}-${pkgrel}"
  )
  conflicts=(
    jre-openjdk
    jre-openjdk-headless
  )
  backup=(
    etc/${pkgbase}/logging.properties
    etc/${pkgbase}/management/jmxremote.access
    etc/${pkgbase}/management/jmxremote.password.template
    etc/${pkgbase}/management/management.properties
    etc/${pkgbase}/net.properties
    etc/${pkgbase}/security/java.policy
    etc/${pkgbase}/security/java.security
    etc/${pkgbase}/security/policy/README.txt
    etc/${pkgbase}/security/policy/limited/default_US_export.policy
    etc/${pkgbase}/security/policy/limited/default_local.policy
    etc/${pkgbase}/security/policy/limited/exempt_local.policy
    etc/${pkgbase}/security/policy/unlimited/default_US_export.policy
    etc/${pkgbase}/security/policy/unlimited/default_local.policy
    etc/${pkgbase}/sound.properties
  )
  install=install_jdk-openjdk.sh

  cd ${_imgdir}/jdk

  install -dm 755 "${pkgdir}${_jvmdir}"

  cp -a bin demo include jmods lib release\
    "${pkgdir}${_jvmdir}"

  rm "${pkgdir}${_jvmdir}/lib/src.zip"

    # Conf
  install -dm 755 "${pkgdir}/etc"
  cp -r conf "${pkgdir}/etc/${pkgbase}"
  ln -s /etc/${pkgbase} "${pkgdir}/${_jvmdir}/conf"

  # Legal
  install -dm 755 "${pkgdir}/usr/share/licenses"
  cp -r legal "${pkgdir}/usr/share/licenses/${pkgbase}"
  ln -s ${pkgbase} "${pkgdir}/usr/share/licenses/${pkgname}"
  ln -s /usr/share/licenses/${pkgbase} "${pkgdir}/${_jvmdir}/legal"

  # Man pages
  for f in bin/*; do
    f=$(basename "${f}")
    _man=../jdk/man/man1/"${f}.1"
    test -f "${_man}" && install -Dm 644 "${_man}" "${pkgdir}/usr/share/man/man1/${f}-openjdk${_majorver}.1"
  done
  ln -s /usr/share/man "${pkgdir}/${_jvmdir}/man"

  # Link JKS keystore from ca-certificates-utils
  rm -f "${pkgdir}${_jvmdir}/lib/security/cacerts"
  ln -sf /etc/pki/tls/java/cacerts "${pkgdir}${_jvmdir}/lib/security/cacerts"

  # Icons
  for s in 16 24 32 48; do
    install -Dm 644 \
      "${srcdir}/${_jdkdir}/src/java.desktop/unix/classes/sun/awt/X11/java-icon${s}.png" \
      "${pkgdir}/usr/share/icons/hicolor/${s}x${s}/apps/java${_majorver}-openjdk.png"
  done

  # Desktop files
  for f in jconsole java jshell; do
    install -Dm 644 \
      "${srcdir}/freedesktop-${f}.desktop" \
      "${pkgdir}/usr/share/applications/${f}-${pkgbase}.desktop"
  done
}

package_openjdk-src() {
  pkgdesc="OpenJDK Java ${_majorver} sources"
  # Depends on JDK to get license files
  depends=("jdk${_majorver}-openjdk=${pkgver}-${pkgrel}")
  provides=("openjdk${_majorver}-src=${pkgver}-${pkgrel}")

  install -Dm 644 -t "${pkgdir}${_jvmdir}/lib" ${_imgdir}/jdk/lib/src.zip

  install -dm 755 "${pkgdir}/usr/share/licenses"
  ln -s ${pkgbase} "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et: