git » liblc3.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: OSAMC <https://github.com/osam-cologne/archlinux-proaudio>
# Contributor: Florian Hülsmann <fh@cbix.de>

pkgname=liblc3
pkgver=1.1.1
pkgrel=1
pkgdesc="Low Complexity Communication Codec library and tools"
url="https://github.com/google/liblc3"
arch=(armv7h)
license=(Apache-2.0)
depends=(glibc)
makedepends=(
  git
  meson
)
provides=(liblc3.so)
source=("git+$url#tag=v$pkgver")
b2sums=('e6492333659b7560104a09917704222e427667dd88d7c87f3ac5b70e67292deede8fa03db870033363e0e4518e3ac2c3fb2a934aa4e5dfcca2140e4301d84944')

prepare() {
  cd liblc3
}

build() {
  arch-meson liblc3 build -D tools=true
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
  install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 liblc3/README.md
}

# vim:set sw=2 sts=-1 et: