git » libmbim.git » commit c843280

diff --git a/PKGBUILD.next b/PKGBUILD.next
new file mode 100644
index 0000000..d4f163c
--- /dev/null
+++ b/PKGBUILD.next
@@ -0,0 +1,42 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+
+pkgname=libmbim
+pkgver=1.24rc1
+pkgrel=1
+pkgdesc="MBIM modem protocol helper library"
+arch=(x86_64)
+url="https://www.freedesktop.org/wiki/Software/libmbim/"
+license=(GPL2)
+depends=(glib2 bash systemd libgudev)
+makedepends=(gtk-doc python git help2man autoconf-archive gobject-introspection)
+_commit=47e2ed70db68f655710a558e03bc0d77e3be96d4  # tags/1.24-rc1
+source=("git+https://gitlab.freedesktop.org/mobile-broadband/libmbim.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-rc/rc/;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --libexecdir=/usr/lib --disable-static --enable-gtk-doc \
+    --enable-compile-warnings=minimum
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}