git » libmtp.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: damir <damir@archlinux.org>
# Contributor: Kevin Edmonds <edmondskevin@hotmail.com>

pkgname=libmtp
pkgver=1.1.21
pkgrel=1
pkgdesc='Library implementation of the Media Transfer Protocol'
arch=(x86_64 'armv7h')
url='http://libmtp.sourceforge.net'
license=(LGPL)
depends=(libusb)
makedepends=(doxygen)
source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz{,.asc})
sha256sums=('c4ffa5ab8c8f48c91b0047f2e253c101c418d5696a5ed65c839922a4280872a7'
            'SKIP')
validpgpkeys=(7C4AFD61D8AAE7570796A5172209D6902F969C95) # Marcus Meißner <meissner@suse.de>

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --with-udev=/usr/lib/udev
  make
}

#check() {
#  cd $pkgname-$pkgver
#  make -k check
#}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

# Install man page
  install -Dm644 doc/man/man3/*.3 -t "$pkgdir"/usr/share/man/man3/
}