git » libnice.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: William Díaz <wdiaz@archlinux.us>

pkgname=libnice
pkgver=0.1.22
pkgrel=1
pkgdesc="An implementation of the IETF's draft ICE (for p2p UDP data streams)"
url="https://nice.freedesktop.org"
arch=(x86_64 'armv7h')
license=('MPL-1.1 OR LGPL-2.1-only')
depends=(
  glib2
  gnutls
  gupnp-igd
)
makedepends=(
  git
  gobject-introspection
  graphviz
 # gstreamer
  gtk-doc
  meson
)
#optdepends=('gstreamer: "nice" GStreamer plugin')
provides=(libnice.so)
_commit=ae3eb16fd7d1237353bf64e899c612b8a63bca8a  # tags/0.1.22^0
source=("git+https://gitlab.freedesktop.org/libnice/libnice.git#commit=$_commit")
b2sums=('SKIP')

pkgver() {
  cd libnice
  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd libnice

  # GUPnP-IGD 1.6
  sed -i 's/gupnp-igd-1\.0/gupnp-igd-1.6/' meson.build
}

build() {
  arch-meson libnice build -D gtk_doc=enabled -D gstreamer=disabled
  meson compile -C build
}

#check() {
#  meson test -C build --print-errorlogs
#}

package() {
  meson install -C build --destdir "$pkgdir"
}

# vim:set sw=2 sts=-1 et: