git » libplacebo.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Robin Candau <antiz@archlinux.org>

pkgname=libplacebo
pkgver=6.338.2
pkgrel=6
pkgdesc='Reusable library for GPU-accelerated video/image rendering primitives'
url='https://github.com/haasn/libplacebo'
arch=('armv7h')
license=('LGPL-2.1-or-later')
depends=('glslang' 'lcms2' 
         'glibc' 'gcc-libs' 'libunwind' 'xxhash')
makedepends=(
  'meson' 'ninja'  'glad' 'nuklear'
  'python' 'python-setuptools' 'python-mako' 'markupsafe' 'jinja2'
  'libglvnd' 'git'
)
provides=('libplacebo.so')
source=(https://code.videolan.org/videolan/libplacebo/-/archive/v${pkgver}/libplacebo-v${pkgver}.tar.gz
	git+https://github.com/KhronosGroup/Vulkan-Headers.git)
sha512sums=('0f20ae47bc2a7cd128d667ec2dd750a2d6ad5f16be6ab97122c2dda1ebf239958ee4bf453a7f835bea2dafb60a2e27b795801532aad994e002854c190aa6bbd8' SKIP)
b2sums=('23485d677fbc59d47cbfd56ac3d5187c18206d7c03b0a7c4decd1d5b5772a88de4e22228cfdfc4fe1ce2c8031ea053cee968d010474047dc511d597d9d5ee3a8' SKIP)

prepare() {
  rm -r ${pkgname}-v${pkgver}/3rdparty/Vulkan-Headers
  mv Vulkan-Headers ${pkgname}-v${pkgver}/3rdparty
}  

build() {
  cd ${pkgname}-v${pkgver}
  CXXFLAGS+=" -I/usr/include/glslang"
  arch-meson build \
    -D tests=false \
    -D vulkan=disabled \
    -D vk-proc-addr=disabled \
    -D glslang=enabled \
    -D shaderc=disabled \
    -D lcms=enabled \
    -D d3d11=disabled \
    -D libdovi=disabled \
    -D demos=false
  meson compile -C build
}

#check() {
#  cd ${pkgname}-v${pkgver}
#  meson test -C build --print-errorlogs
#}

package() {
  depends+=(
    'liblcms2.so'
  )

  cd ${pkgname}-v${pkgver}
  meson install -C build --destdir "${pkgdir}"
  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}

# vim:set sw=2 sts=-1 et: