git » libqmi.git » commit 3c3903a

diff --git a/PKGBUILD b/PKGBUILD
index fe319ed..60429ee 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,16 +1,16 @@
 # Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
 
 pkgname=libqmi
-pkgver=1.24.12
+pkgver=1.24.14
 pkgrel=1
 pkgdesc="QMI modem protocol helper library"
 arch=(x86_64)
 url="https://www.freedesktop.org/wiki/Software/libqmi/"
 license=(GPL2)
 depends=(libmbim libgudev)
-makedepends=(gtk-doc python git help2man)
+makedepends=(gtk-doc python git help2man autoconf-archive)
 provides=(libqmi-glib.so)
-_commit=b5336c9dcfb11d3843d6093cf43328164588a80f  # tags/1.24.12
+_commit=a28c43bac61851f32abafef2922f2c237a0ff06d  # tags/1.24.14
 source=("git+https://gitlab.freedesktop.org/mobile-broadband/libqmi.git#commit=$_commit")
 sha256sums=('SKIP')
 
diff --git a/PKGBUILD.next b/PKGBUILD.next
new file mode 100644
index 0000000..9bca638
--- /dev/null
+++ b/PKGBUILD.next
@@ -0,0 +1,43 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+
+pkgname=libqmi
+pkgver=1.26rc1
+pkgrel=1
+pkgdesc="QMI modem protocol helper library"
+arch=(x86_64)
+url="https://www.freedesktop.org/wiki/Software/libqmi/"
+license=(GPL2)
+depends=(libmbim libgudev)
+makedepends=(gtk-doc python git help2man autoconf-archive gobject-introspection)
+provides=(libqmi-glib.so)
+_commit=ef9e0ea2ddee417f7f85388b7779750c846aaeca  # tags/1.26-rc1
+source=("git+https://gitlab.freedesktop.org/mobile-broadband/libqmi.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-rc/rc/;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --libexecdir=/usr/lib --disable-static --enable-gtk-doc \
+    --enable-compile-warnings=minimum
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}