git » libvorbis.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Tobias Kieslich <tobias@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>
# Contributor: John Proctor <jproctor@prium.net>

pkgname=libvorbis
pkgver=1.3.7
pkgrel=3
pkgdesc='Reference implementation of the Ogg Vorbis audio format'
arch=(armv7h 'aarch64')
url=https://www.xiph.org/vorbis/
license=(BSD)
depends=(libogg.so)
makedepends=(git)
provides=(
  libvorbis.so
  libvorbisenc.so
  libvorbisfile.so
)
_tag=0c55fa38933fd4bdb7db7c298b27e7bf2f2c5e98
source=(git+https://github.com/xiph/vorbis.git?signed#tag=${_tag})
validpgpkeys=(B7B00AEE1F960EEA0FED66FB9259A8F2D2D44C84) # Ralph Giles <giles@thaumas.net>
sha256sums=(SKIP)

pkgver() {
  cd vorbis

  git describe --tags | sed 's/^v//'
}

prepare() {
  cd vorbis

  ./autogen.sh
}

build() {
  cd vorbis

  ./configure \
    --prefix=/usr \
    --disable-static \
    --enable-shared
  make
}

check() {
  make -j1 -C vorbis check
}

package() {
  make DESTDIR="${pkgdir}" -C vorbis install
  install -Dm 644 vorbis/COPYING -t "${pkgdir}"/usr/share/licenses/libvorbis
}

# vim: ts=2 sw=2 et: