git » libzmf.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
# Maintainer: AndyRTR <andyrtr@archlinux.org>

pkgname=libzmf
pkgver=0.0.2
pkgrel=16
pkgdesc="a library for import of Zoner drawing and bitmap files"
arch=('x86_64' 'armv7h')
url="https://wiki.documentfoundation.org/DLP/Libraries/libzmf"
license=('MPL')
source=(https://dev-www.libreoffice.org/src/${pkgname}/${pkgname}-${pkgver}.tar.xz)
depends=('librevenge' 'libpng'
         'zlib' 'icu' 'gcc-libs' 'glibc')
makedepends=('boost' 'cppunit' 'doxygen')
sha256sums=('27051a30cb057fdb5d5de65a1f165c7153dc76e27fe62251cbb86639eb2caf22')

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr --disable-werror
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}