git » neon.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>

pkgname=neon
pkgver=0.33.0
pkgrel=1
pkgdesc='HTTP/1.1 and WebDAV client library'
arch=('armv7h')
url='https://notroj.github.io/neon/'
license=('LGPL-2.0-or-later')
depends=('ca-certificates' 'expat' 'glibc' 'krb5' 'openssl' 'zlib')
makedepends=('docbook-xsl' 'git' 'xmlto')
source=("git+https://github.com/notroj/neon.git#tag=$pkgver")
b2sums=('6f40999cca23e0379c1fb28b790ae5df34790a7da5826b1256167b86950aaceaaa99ef358df8610aa6d91e21c379c20da33dafced5b8b201e067b5d3d8ed8e3c')
validpgpkeys=('190555472DCC589BEF01609C608A86DF9833CC49') # Joe Orton

prepare() {
  cd $pkgname

  # Fix for autoreconf
  git cherry-pick -n 23a4e2fbb1965013fe066255cb60bb318bbfb4f6

  echo $pkgver > .version
  autoreconf -fi
}

build() {
  cd $pkgname
  ./configure --prefix=/usr \
    --enable-shared \
    --with-ssl=openssl \
    --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt
  make
  make docs compile-gmo
}

check() {
  cd $pkgname
  make check
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}