git » physfs.git » commit 340cf7b

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..0bf5605
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Eric Bélanger <eric@archlinux.org>
+
+pkgname=physfs
+pkgver=3.0.1
+pkgrel=1
+pkgdesc="A library to provide abstract access to various archives"
+arch=('x86_64')
+url="http://icculus.org/physfs/"
+license=('ZLIB')
+depends=('zlib')
+makedepends=('cmake' 'doxygen')
+source=(http://icculus.org/physfs/downloads/${pkgname}-${pkgver}.tar.bz2)
+sha1sums=('9959a7acad0aa30d1a86d3a418e61155b0ac533c')
+
+build() {
+  mkdir build
+  cd build
+  cmake ../${pkgname}-${pkgver} -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DPHYSFS_BUILD_TEST=OFF
+  make all docs
+}
+
+package() {
+  cd build
+  make DESTDIR="${pkgdir}" install
+  install -d "${pkgdir}"/usr/share/{doc/physfs,man/man3}
+  install -m644 docs/html/* "${pkgdir}/usr/share/doc/physfs"
+  install -m644 docs/man/man3/* "${pkgdir}/usr/share/man/man3"
+
+  for i in author Deinit description extension Free Init major Malloc minor opaque patch Realloc remove url ; do
+    mv "${pkgdir}/usr/share/man/man3/$i.3" "${pkgdir}/usr/share/man/man3/PHYSFS_$i.3"
+  done
+
+  install -D -m644 ../${pkgname}-${pkgver}/LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}