git » pygobject.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgbase=pygobject
pkgname=(
  python-gobject
)
pkgver=3.48.2
pkgrel=1
pkgdesc="Python bindings for GLib/GObject/GIO/GTK"
url="https://pygobject.gnome.org/"
arch=('armv7h' 'aarch64')
license=(LGPL-2.1-or-later)
depends=(
  gobject-introspection-runtime
  python
)
makedepends=(
  git
  gobject-introspection
  meson
  python-cairo
  python-setuptools
)
optdepends=('cairo: Cairo bindings')
source=("git+https://gitlab.gnome.org/GNOME/pygobject.git?signed#tag=$pkgver")
b2sums=('6cd9fd5022fec4c93d844079e3cc0c124f8aed52d390a6b46c536a097b79be8452590a31ba5ce03fb77e3dc0dc2c744fd9efa1135d878c81935c8cd58f4df8b3')
validpgpkeys=(
  0EBF782C5D53F7E5FB02A66746BD761F7A49B0EC # Christoph Reiter <reiter.christoph@gmail.com>
)

prepare() {
  cd pygobject
}

build() {
  arch-meson pygobject build
  meson compile -C build
}


package_python-gobject() {
  provides=("pygobject-devel=$pkgver")
  conflicts=(pygobject-devel)
  replaces=('pygobject-devel<=3.36.1-1')

  meson install -C build --destdir "$pkgdir"
  python -m compileall -d /usr/lib "$pkgdir/usr/lib"
  python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
}

#package_python-gobject-docs() {
#  pkgdesc="Developer documentation for PyGObject"
#  depends=()
#  optdepends=()
#  python -m sphinx -b html pygobject/docs "$pkgdir/usr/share/doc/pygobject/html"
#  rm -r "$pkgdir/usr/share/doc/pygobject/html/.doctrees"
#}


# vim:set sw=2 sts=-1 et: