git » python-sphinx_rtd_theme.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Daniel M. Capella <polyzen@archlinux.org>
# Contributor: eolianoe <eolianoe [at] gmail [DoT] com>
# Contributor: Romain Schmitz <slopjong .at. slopjong .dot. de>

pkgname=python-sphinx_rtd_theme
_name=${pkgname/python-/}
pkgver=1.3.0
pkgrel=2
pkgdesc='Read the Docs theme for Sphinx'
arch=('any')
url=https://github.com/readthedocs/sphinx_rtd_theme
license=('MIT')
depends=('python' 'python-sphinx' 'python-sphinxcontrib-jquery')
makedepends=('python-setuptools-scm' 'python-build' 'python-installer' 'python-wheel')
source=("$_name-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('637611d42a95719235bf557567fadfea89d9e13c5e819f07640f74b75db90dd8')
b2sums=('bc439cf68f7e66a53b73105d423af8159050cb1748ff9fd7e9e3bbda30e79d6745fa4c9325cbf9cca8fd5ec6ed5ec7a7ec386ba4c303cf54f5de5387b901a73b')

build() {
  cd "$_name"-$pkgver
  SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver python -m build --wheel --no-isolation
}

package() {
  cd "$_name"-$pkgver
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname LICENSE
}

# vim:set ts=2 sw=2 et: