git » raptor.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
# Contributor: eric <eric@archlinux.org>
# Contributor: Damir Perisa <damir.perisa@bluewin.ch>

_name=raptor2
pkgname=raptor
pkgver=2.0.16
pkgrel=6
pkgdesc="A C library that parses RDF/XML/N-Triples into RDF triples"
arch=(armv7h)
url="https://librdf.org/raptor"
license=(Apache GPL2 LGPL2.1)
depends=(glibc libxml2 libxslt xz zlib)
makedepends=(curl gtk-doc icu)
provides=(libraptor2.so)
source=(https://librdf.org/dist/source/$_name-$pkgver.tar.gz{,.asc}
        raptor-2.0.15-libxml2-2.11.patch)
sha512sums=('9bd5cff36390e1e0ef15ac56e5413ecfceb4018cb531a4da8850d3623615f12a93690a78be61f9d9ae7a24e16f6446e356bc2b7f34051ddc077761d85a9b7c44'
            'SKIP'
            '6d6c6ab0be9136ccf3e5b0c1140e88a49cbf94d4c36d27e3bb672ef13c83cdc7c8048c7ef883f9302fb3924ed78db1b059a983b9e1f8bce4522d5ef33a811ba7')
b2sums=('1e5e5742ba4cdaacb98a9ba77a9352589df0da60869e7721ee140c81ed4886bf909b37b247bd925c82a4ac44b3c11a909c913f0851d49a1d9d91c9293189266d'
        'SKIP'
        '0e3462817a77917eb82066f7d9efb1a28fa27221596c18fb140dadb4c0fd074b0936ed5cbd9fc620548796f548ad75890b00a3f73300af7d754cea695dc7f993')
validpgpkeys=('F879F0DEDA780198DD08DC6443EC92504F71955A') # Dave Beckett <dave@dajobe.org>

prepare() {
  cd $_name-$pkgver
  patch -Np1 -i ../raptor-2.0.15-libxml2-2.11.patch
  autoreconf -fiv
}

build() {
  local configure_options=(
    --prefix=/usr
    --disable-static
    --with-icu-config=/usr/bin/icu-config
  )

  cd $_name-$pkgver
  ./configure "${configure_options[@]}"
  # prevent excessive overlinking due to libtool
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  # run with one job as tests are otherwise flaky: https://github.com/dajobe/raptor/issues/49
  make check -C $_name-$pkgver -j1
}

package() {
  depends+=(
    curl # libcurl.so
    icu libicuuc.so
  )

  make DESTDIR="$pkgdir" install -C $_name-$pkgver
  install -vDm 644 $_name-$pkgver/{AUTHORS,ChangeLog*,README} -t "$pkgdir/usr/share/doc/$pkgname/"
}