git » rdfind.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Christian Kohlstedde <christian+aur@kohlsted.de>
# Contributor: Mariusz Libera <mariusz.libera@gmail.com>
# Contributor: Alex 'AdUser' Z <ad_user@mail.ru>

pkgname=rdfind
pkgver=1.6.0
pkgrel=2
pkgdesc='Redundant data find - a program that finds duplicate files'
arch=('x86_64' 'armv7h')
url='https://rdfind.pauldreik.se'
license=('GPL-2.0-only')
depends=('nettle' 'glibc' 'gcc-libs')
source=("${url}/${pkgname}-${pkgver}.tar.gz"{,.asc})
sha256sums=('7a406e8ef1886a5869655604618dd98f672f12c6a6be4926d053be65070f3279'
            'SKIP')
validpgpkeys=("CC3C51BA88205B19728A6F07C9D9A0EA44EAE0EB")

build() {
  cd "${pkgname}-${pkgver}"
  ./configure --prefix=/usr
  make
}

check() {
  cd "${pkgname}-${pkgver}"
  make check
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  install -dm755 "${pkgdir}/usr/share/doc/${pkgname}"
  install -m644 AUTHORS ChangeLog README "${pkgdir}/usr/share/doc/${pkgname}"
}