git » ruby-debug.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
_gemname=debug
pkgname=ruby-${_gemname}
pkgver=1.7.1
pkgrel=1
pkgdesc='Debugging functionality for Ruby'
url='https://github.com/ruby/debug'
arch=(x86_64 'armv7h')
license=('BSD-2-Clause')
depends=(
  ruby
  ruby-irb
  ruby-reline
)
makedepends=(
  git
  ruby-rdoc
  ruby-rake
  ruby-bundler
)
#checkdepends=(
#  ruby-test-unit
#  ruby-test-unit-rr
#)
options=('!emptydirs')
source=(${pkgname}::git+"${url}#tag=v${pkgver}")
sha512sums=('888cff32b1497235a53719dfb46a46e3360b6b2e6b4b177937c5ed1d80774af845cf91d29f33833490aa4720d8cbc513e5a50f7648b320bb4174e733c0d1fb70')

prepare() {
  cd ${pkgname}
  sed '/assert_equal(expected, colored_inspect(obj))/d' -i test/console/color_test.rb
}

build() {
  cd ${pkgname}
  rake build
}

#check() {
#  cd ${pkgname}
#  export RUBY_DEBUG_TEST_NO_REMOTE=1
#  rake test_console
#}

package() {
  cd ${pkgname}
  local _gemdir="$(gem env gemdir)"
  gem install --verbose --ignore-dependencies --no-user-install \
    --install-dir "${pkgdir}/${_gemdir}" --bindir "${pkgdir}/usr/bin" pkg/"${_gemname}-${pkgver}.gem"

  if [[ ! -f "${pkgdir}/usr/bin/rdbg" ]]; then
    error "missing /usr/bin/rdbg"
    exit 1
  fi

  rm -rf "${pkgdir}/${_gemdir}/cache"
  rm -rf "${pkgdir}/${_gemdir}/gems/${_gemname}-${pkgver}/.github"

  install -Dm 644 README.md  -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et: