git » tk.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Eric Bélanger <eric@archlinux.org>

pkgname=tk
pkgver=8.6.14
pkgrel=3
pkgdesc='A windowing toolkit for use with tcl'
arch=(x86_64 'armv7h')
url="http://tcl.sourceforge.net/"
license=(TCL)
depends=(tcl
         libxss
         libxft)
options=(staticlibs)
_archive="$pkgname$pkgver"
source=("https://downloads.sourceforge.net/sourceforge/tcl/$_archive-src.tar.gz")
sha256sums=('8ffdb720f47a6ca6107eac2dd877e30b0ef7fac14f3a84ebbd0b3612cee41a94')

build() {
	cd "$_archive/unix"
	./configure \
		--prefix=/usr \
		--mandir=/usr/share/man \
		--enable-threads \
		--disable-rpath \
		--enable-64bit
	make
}

check() {
	cd "$_archive/unix"
	#  make test
}

package() {
	cd "$_archive/unix"
	make INSTALL_ROOT="$pkgdir" install install-private-headers
	ln -sf wish${pkgver%.*} "$pkgdir/usr/bin/wish"
	ln -sf libtk${pkgver%.*}.so "$pkgdir/usr/lib/libtk.so"
	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" license.terms

	# install private headers (FS#14388, FS#47616)
	cd ..
	for dir in compat generic generic/ttk unix; do
		install -dm755 "$pkgdir/usr/include/tk-private/$dir"
		install -m644 -t "$pkgdir/usr/include/tk-private/$dir" $dir/*.h
	done

	# remove buildroot traces
	sed -e "s#$srcdir/$_archive/unix#/usr/lib#" \
		-e "s#$srcdir/$_archive#/usr/include#" \
		-i "$pkgdir/usr/lib/tkConfig.sh"

	# remove unrequired execute permissions (FS#75042)
	chmod -x "$pkgdir/usr/lib/libtkstub8.6.a"
}