git » readline.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
pkgname=readline
pkgver=8.2
pkgrel=1
arch=('armv7h' 'aarch64')
license=('unknown')
source=("$pkgname-$pkgver.tar.gz"
	"readline-8.2-upstream_fixes-3.patch")
depends=(glibc ncurses)
provides=('libreadline.so')

prepare() {
	cd "$pkgname-$pkgver"
	sed -i '/MV.*old/d' Makefile.in
	sed -i '/{OLDSUFF}/c:' support/shlib-install
	patch -Np1 -i "$srcdir/readline-8.2-upstream_fixes-3.patch"
}

build() {
	cd "$pkgname-$pkgver"
	./configure --prefix=/usr    \
            --disable-static \
            --with-curses    \
            --docdir=/usr/share/doc/readline-8.2
	make SHLIB_LIBS="-lncursesw"
}

package() {
	cd "$pkgname-$pkgver"
	make DESTDIR="$pkgdir/" SHLIB_LIBS="-lncursesw" install
	install -v -m644 doc/*.{ps,pdf,html,dvi} "$pkgdir"/usr/share/doc/readline-8.2
}
sha256sums=('3feb7171f16a84ee82ca18a36d7b9be109a52c04f492a053331d7d1095007c35'
            '8a108b34c5bdf9d6a9d6c0bd4cf2da756ae5232c5de2ae55c5468e953bb8de62')