git » attica.git » commit fbda9d9

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..02b7c93
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# $Id: PKGBUILD 314683 2018-01-13 13:44:15Z arojas $
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Maintainer: Antonio Rojas <arojas@archlinux.org>
+# Contributor: Andrea Scarpino <andrea@archlinux.org>
+
+pkgname=attica
+pkgver=5.43.0
+pkgrel=1
+arch=(x86_64)
+pkgdesc='Qt library that implements the Open Collaboration Services API'
+url='https://community.kde.org/Frameworks'
+license=(LGPL)
+depends=(qt5-base)
+makedepends=(extra-cmake-modules doxygen qt5-tools)
+groups=(kf5)
+conflicts=(attica-qt5)
+provides=(attica-qt5)
+replaces=(attica-qt5)
+source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('2ac4197eb97fd09bafbfe91bb90b9cf0cc8e65f2cdc20cd54ba63adb402b6eef'
+            'SKIP')
+validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_QCH=ON
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}