git » gegl.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
# Maintainer: Christian Hesse <mail@eworm.de>
# Maintainer: Christian Heusel <gromit@archlinux.org>
# Contributor: Daniel Isenmann <daniel@archlinux.org>

pkgname=gegl
pkgver=0.4.48
pkgrel=4
pkgdesc='Graph based image processing framework'
arch=('x86_64' 'armv7h')
url='https://www.gegl.org/'
license=('GPL-3.0-or-later OR LGPL-3.0-or-later')
depends=('babl' 'cairo' 'gcc-libs' 'gdk-pixbuf2' 'glib2' 'glibc' 'jasper' 'json-glib' 'lcms2'
         'lensfun' 'libjpeg-turbo' 'libpng' 'libraw' 'librsvg' 'libspiro' 'libtiff' 'libwebp'
         'luajit' 'openexr' 'pango' 'poppler-glib' 'suitesparse')
makedepends=('ffmpeg' 'git' 'gobject-introspection' 'libgexiv2' 'meson' 'python-gobject' 'sdl2'
             'vala' #'gi-docgen'
)
optdepends=('ffmpeg: FFmpeg Frame Loader and FFmpeg Frame Saver plugins'
            'graphviz: for gegl-introspect'
            'sdl2: SDL2 Display plugin')
source=("git+https://gitlab.gnome.org/GNOME/gegl.git#tag=GEGL_${pkgver//./_}")
sha256sums=('bed1b1f0348519a175422800564c65c372b125b4230a0207342911bf07f34ded')

prepare() {
  cd "${pkgname}"
  # https://gitlab.archlinux.org/archlinux/packaging/packages/gegl/-/issues/1
  # https://gitlab.gnome.org/GNOME/gegl/-/issues/368
  git cherry-pick --mainline 1 --no-commit \
      ab6c62963dff7c7d464f4453f2f3f554221e5c16 \
      a54105e15c9012933b5d830a32aef76f4e04290e \
      66de8124f496617eee8e6b5c68138a00343882db \
      298b6a2afb87b4b5b15c6e715967b57534cd0af0
}

pkgver() {
  cd "${pkgname}"
  git describe --tags | sed 's/^GEGL_//;s/_$//;s/_/./g;s/-/+/g'
}

build() {
  mkdir -p build
  cd build
  arch-meson ../"${pkgname}" \
    -Dworkshop=true \
    -Dmrg=disabled \
    -Dmaxflow=disabled \
    -Dgtk-doc=false \
    -Ddocs=false \
    -Dgi-docgen=disabled

  ninja
}

#check() {
#  cd build
#  ninja test || :
#}

package() {
  cd build
  DESTDIR="${pkgdir}" ninja install
}