git » kate.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=kate
pkgver=23.08.5
pkgrel=1
arch=(x86_64 'armv7h')
license=(GPL LGPL FDL)
pkgdesc='Advanced text editor'
groups=(kde-applications kde-utilities)
url='https://apps.kde.org/kate/'
depends=(knewstuff ktexteditor kactivities kuserfeedback hicolor-icon-theme)
optdepends=('konsole: open a terminal in Kate'
            'clang: C and C++ LSP support'
            'python-lsp-server: Python LSP support'
            'texlab: LaTeX LSP support'
            'rust: Rust LSP support'
            'git: git-blame plugin')
makedepends=(extra-cmake-modules kdoctools)
conflicts=(kwrite)
provides=(kwrite)
replaces=(kwrite)
source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
sha256sums=('683c49d9c4b2abd4b4660b607b65249a2adfdc48418b0d18ab90810d1a8f4e37'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}