git » signon-plugin-oauth2.git » main » tree

[main] / PKGBUILD 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Balló György <ballogyor+arch at gmail dot com>

pkgname=signon-plugin-oauth2
_pkgname=signon-oauth2
pkgver=0.25
pkgrel=3
pkgdesc='OAuth 2 plugin for signon'
arch=(x86_64 'armv7h')
url='https://gitlab.com/accounts-sso/signon-plugin-oauth2'
license=(LGPL)
depends=(gcc-libs
         glibc
         qt5-base
         signond)
makedepends=(git)
# source=(https://gitlab.com/accounts-sso/signon-plugin-oauth2/-/archive/VERSION_$pkgver/signon-plugin-oauth2-VERSION_$pkgver.tar.bz2)
_commit=fab698862466994a8fdc9aa335c87b4f05430ce6
source=(git+https://gitlab.com/nicolasfella/signon-plugin-oauth2#commit=$_commit)
sha256sums=('SKIP')

prepare() {
  cd $pkgname

  # Do not install tests and example
  echo 'INSTALLS =' >>tests/tests.pro
  echo 'INSTALLS =' >>example/example.pro
}

build() {
  cd $pkgname

  qmake \
    PREFIX=/usr \
    LIBDIR=/usr/lib
  make
}

package() {
  cd $pkgname

  make INSTALL_ROOT="$pkgdir" install
}